lien-openaria/tests/250_suivi.robot

*** Settings ***
Documentation  Rubrique Suivi.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown
# A chaque début de Test Case on se positionne sur le tableau bord administrateur
Test Setup  Depuis la page d'accueil  admin  admin


*** Test Cases ***
Constitution du jeu de données

    [Documentation]  Constitue le jeu de données.

    # Date du jour au format : JJ/MM/AAAA
    ${date_jour} =  Date du jour FR
    Set Suite Variable  ${date_jour}


Réponse à une consultation par la cellule suivi

    [Documentation]  La cellulle suivi peut saisir les retours de consultation
    ...  reçus par papier directement à l'aide d'un code barre présent sur les
    ...  demandes d'avis.

    ##
    ## Constitution du jeu de données
    ##
    #
    # Le dossier di_01 est affecté à l'instructeur "Louis Laurent" (instr) division "H"
    #
    #
    &{args_petitionnaire_01} =  Create Dictionary
    ...  particulier_nom=DUPONT
    ...  particulier_prenom=Jacques
    #
    &{args_demande_01} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  date_demande=12/04/2015
    #
    ${service} =  Set Variable  59.01 - Direction de l'Eau et de l'Assainissement
    #
    Depuis la page d'accueil  guichet  guichet
    ${di_01} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande_01}  ${args_petitionnaire_01}
    #
    Depuis la page d'accueil  instr  instr
    Ajouter une consultation depuis un dossier  ${di_01}  ${service}
    Depuis le contexte de la consultation  ${di_01}  ${service}
    ${consultation_id} =  Get Text  css=div#form-content span#consultation
    ${consultation_codebarres} =  STR_PAD_LEFT  ${consultation_id}  10  0
    ${consultation_codebarres} =  Catenate  12${consultation_codebarres}

    ##
    ##
    ##

    # On se connecte en tant que "suivi"
    Depuis la page d'accueil  suivi  suivi

    # On accède à l'écran de saisie des retours de consultation
    Go To Submenu In Menu  suivi  consultation-retour
    Page Title Should Be  Suivi > Demandes D'avis > Retours De Consultation
    First Tab Title Should Be  Saisir Un Retour De Consultation

    # On clique sur le bouton "Valider" sans saisir de code barres
    Click On Submit Button
    Error Message Should Be  Veuiller saisir un code barres de consultation.

    #
    Input Text  code_barres  '?#
    Click On Submit Button
    Error Message Should Be  Cette consultation n'existe pas.

    #
    Input Text  code_barres  aze
    Click On Submit Button
    Error Message Should Be  Cette consultation n'existe pas.

    # Saisie d'un code barre valide
    Input Text  code_barres  ${consultation_codebarres}
    Click On Submit Button  ne_pas_verifier_le_message
    # On vérifie que les valeurs du formulaire corresponde
    Page Title Should Be  Suivi > Demandes D'avis > Retours De Consultation > ${consultation_id}
    Form Value Should Be  css=#consultation  ${consultation_id}
    Form Value Should Be  css=#dossier_libelle  ${di_01}

    # On clique sur le lien retour
    Click On Back Button
    # On vérifie que le retour nous mène bien à l'écran de saisie des retours de consultation
    Go To Submenu In Menu  suivi  consultation-retour
    Page Title Should Be  Suivi > Demandes D'avis > Retours De Consultation
    First Tab Title Should Be  Saisir Un Retour De Consultation

    # Saisie d'un code barre valide
    Input Text  code_barres  ${consultation_codebarres}
    Click On Submit Button  ne_pas_verifier_le_message
    # On vérifie que les valeurs du formulaire corresponde
    Page Title Should Be  Suivi > Demandes D'avis > Retours De Consultation > ${consultation_id}
    Form Value Should Be  css=#consultation  ${consultation_id}
    Form Value Should Be  css=#dossier_libelle  ${di_01}
    # Saisie des valeurs dans le formulaire
    Select From List By Label  css=select#avis_consultation  Favorable
    Input Text  css=textarea#motivation  blablabla
    Add File  fichier  lettre_rar16042013124515.pdf
    Click On Submit Button
    # On vérifie que le message de validation est présent
    Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # On clique sur le lien retour
    Click On Back Button
    # On vérifie que le retour nous mène bien à l'écran de saisie des retours de consultation
    Go To Submenu In Menu  suivi  consultation-retour
    Page Title Should Be  Suivi > Demandes D'avis > Retours De Consultation
    First Tab Title Should Be  Saisir Un Retour De Consultation


TNR Bug "Erreur de base de données" lors de la saisie de caractère spéciaux dans le champ code barre du formulaire de suivi mise à jour des dates des instructions

    [Documentation]

    #
    Depuis la page d'accueil  suivi  suivi
    # On change de contexte pour que l'ouverture de menu suivante fonctionne
    Go To Tab  dossier_autorisation
    # Saisie de Mise à jour des dates
    Go To Submenu In Menu    suivi    suivi_mise_a_jour_des_dates
    Input Text  date  12/05/2015
    Input Text  code_barres  '?#
    # On valide le formulaire
    Click On Submit Button
    # On ne fait aucune vérification ici car le keyword précédent "Click On
    # Submit Button" permet de vérifier qu'il n'y a pas d'erreur de base de
    # données


TNR Bug "Erreur de base de données" lors de la saisie de caractère spéciaux dans le champ code barre du formulaire de suivi mise à jour des dates des demandes d'avis

    [Documentation]

    #
    Depuis la page d'accueil  suivi  suivi
    # On change de contexte pour que l'ouverture de menu suivante fonctionne
    Go To Tab  dossier_autorisation
    # Saisie de Mise à jour des dates
    Go To Submenu In Menu    suivi    demandes_avis_mise_a_jour_des_dates
    Input Text  date  12/05/2015
    Input Text  code_barres  '?#
    # On valide le formulaire
    Click On Submit Button
    # On ne fait aucune vérification ici car le keyword précédent "Click On
    # Submit Button" permet de vérifier qu'il n'y a pas d'erreur de base de
    # données


TNR Bug "Erreur de base de données" lors de la saisie de caractère spéciaux dans le champ code barre du formulaire de suivi du bordereau d'envoi au maire

    [Documentation]

    #
    Depuis la page d'accueil  admin  admin
    # On change de contexte pour que l'ouverture de menu suivante fonctionne
    Go To Tab  dossier_autorisation
    # Saisie de Mise à jour des dates
    Go To Submenu In Menu    suivi    bordereau_envoi_maire
    Input Text  date  12/05/2015
    Input Text  code_barres  '?#
    # On valide le formulaire
    Click On Submit Button
    # On ne fait aucune vérification ici car le keyword précédent "Click On
    # Submit Button" permet de vérifier qu'il n'y a pas d'erreur de base de
    # données


TNR Bug "Erreur de base de données" lors de la prévisualisation des bordereaux.

    [Documentation]  Vérifie qu'il n'a aucune erreur lors de la prévisualisation
    ...  des bordereaux depuis le menu des états.

    #
    Depuis la page d'accueil  admin  admin
    # On change de contexte pour que l'ouverture de menu suivante fonctionne
    Go To Tab  dossier_autorisation
    # Saisie de Mise à jour des dates
    Go To Submenu In Menu    parametrage-dossier    om_etat
    # On fait une recherche sur l'identifiant de l'état
    Use Simple Search  id  bordereau_courriers_signature_maire
    # On sélectionne le résultat
    Click On Link  bordereau_courriers_signature_maire
    # On clic sur l'action de prévisualisation
    Click On Form Portlet Action  om_etat  previsualiser
    # On ouvre le PDF
    Open PDF  form
    # On vérifie qu'il n'y a pas d'erreur
    Sleep  1
    Page Should Not Contain Errors
    # On ferme le PDF
    Close PDF
    # On clic sur le bouton de retour
    Click On Back Button
    # On fait une recherche sur l'identifiant de l'état
    Use Simple Search  id  bordereau_avis_maire_prefet
    # On sélectionne le résultat
    Click On Link  bordereau_avis_maire_prefet
    # On clic sur l'action de prévisualisation
    Click On Form Portlet Action  om_etat  previsualiser
    # On ouvre le PDF
    Open PDF  form
    # On vérifie qu'il n'y a pas d'erreur
    Sleep  1
    Page Should Not Contain Errors
    # On ferme le PDF
    Close PDF
    # On clic sur le bouton de retour
    Click On Back Button
    # On fait une recherche sur l'identifiant de l'état
    Use Simple Search  id  bordereau_controle_legalite
    # On sélectionne le résultat
    Click On Link  bordereau_controle_legalite
    # On clic sur l'action de prévisualisation
    Click On Form Portlet Action  om_etat  previsualiser
    # On ouvre le PDF
    Open PDF  form
    # On vérifie qu'il n'y a pas d'erreur
    Sleep  1
    Page Should Not Contain Errors
    # On ferme le PDF
    Close PDF
    # On clic sur le bouton de retour
    Click On Back Button
    # On fait une recherche sur l'identifiant de l'état
    Use Simple Search  id  bordereau_decisions
    # On sélectionne le résultat
    Click On Link  bordereau_decisions
    # On clic sur l'action de prévisualisation
    Click On Form Portlet Action  om_etat  previsualiser
    # On ouvre le PDF
    Open PDF  form
    # On vérifie qu'il n'y a pas d'erreur
    Sleep  1
    Page Should Not Contain Errors
    # On ferme le PDF
    Close PDF
    # On clic sur le bouton de retour
    Click On Back Button


TNR Mise à jour des dates après le délai de notification au pétitionnaire

    [Documentation]  Vérification du message d'erreur lors de la mise à jour de
    ...  la date de retour AR

    #
    Depuis la page d'accueil  guichetsuivi  guichetsuivi
    #
    &{args_petitionnaire} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=SCP
    ...  personne_morale_raison_sociale=Société
    ...  personne_morale_civilite=Monsieur
    ...  personne_morale_nom=Martinez
    ...  personne_morale_prenom=Nicolas

    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  date_demande=12/05/2015

    ${di_02} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    Depuis la page d'accueil  instrpoly  instrpoly
    Ajouter une instruction au DI  ${di_02}  Notification de pieces manquante  12/05/2015
    Click On Back Button In Subform
    Click On Link  Notification de pieces manquante
    Click On SubForm Portlet Action  instruction  finaliser
    ${id_instruction} =  Get Text  css=div#form-content span#instruction
    # On en déduit le code-barres
    ${code_barres} =  STR_PAD_LEFT  ${id_instruction}  10  0
    ${code_barres} =  Catenate  11${code_barres}
    Set Suite Variable  ${code_barres}

    #
    Depuis la page d'accueil  guichetsuivi  guichetsuivi
    # Saisie de Mise à jour des dates
    Go To Submenu In Menu    suivi    suivi_mise_a_jour_des_dates
    Select From List By Label    css=#type_mise_a_jour    date de retour de l'AR
    Input Text  date  12/07/2015
    Input Text  code_barres  ${code_barres}
    # On valide le formulaire
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Click Element  css=#formulaire div.formControls input[type="submit"]
    # On valide la synthèse
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Click Element  css=#formulaire div.formControls input[type="submit"]

    # Vérification des messages d'erreur
    Wait Until Keyword Succeeds     ${TIMEOUT}     ${RETRY_INTERVAL}    Element Should Contain    css=div.ui-state-error p span.text  Problème de dates : contactez l'instructeur du dossier
    Element Should Contain    css=div.ui-state-error p span.text  (date d'évènement <= date limite de notification au pétitionnaire)
    Element Should Contain    css=div.ui-state-valid p span.text  Saisie enregistrée

    # Vérification que l'événement retour n'est pas inséré
    Depuis l'onglet instruction du dossier d'instruction  ${di_02}
    Page Should Not Contain  incomplétude après accusé de réception


Paramétrage des tests sur les bordereaux

    [Documentation]  Crée 2 dossiers sur 2 collectivités différentes, et fait le
    ...  paramétrage nécessaire aux tests sur les bordereaux

    # DA sur la collectivite Marseille
    Depuis la page d'accueil  guichet  guichet

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Chesnay
    ...  particulier_prenom=Roger
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial

    ${di} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    # DA sur la collectivite Allauch
    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3

    &{args_petitionnaire} =  Create Dictionary
    ...  particulier_nom=Sevier
    ...  particulier_prenom=André
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial

    ${di_allauch} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    # Variables disponibles dans tout le test suite
    Set Suite Variable  ${di}
    Set Suite Variable  ${di_allauch}

    Depuis la page d'accueil  suivi  suivi
    Click Link  Bordereaux
    Click On Submit Button
    # Vérification des messages d'erreur
    Error Message Should Contain  Veuillez sélectionner un bordereau
    Select From List By Label  bordereau  Bordereau d'envoi des avis du Maire au Préfet
    Input Text  date_bordereau_debut  null
    Input Text  date_bordereau_fin  null
    Click On Submit Button
    Error Message Should Contain  Veuillez saisir une date valide

    # On change la valeur de id_evenement_bordereau_avis_maire_prefet pour pouvoir tester
    Depuis la page d'accueil  admin  admin
    Go To Tab  om_parametre
    Use Simple Search  libellé  id_evenement_bordereau_avis_maire_prefet
    Click on Link  id_evenement_bordereau_avis_maire_prefet
    Click On Form Portlet Action  om_parametre  modifier
    Input Text  valeur  81
    Click On Submit Button
    # Vérification des messages d'erreur
    Valid Message Should Contain  Vos modifications ont bien été enregistrées
    Click On Back Button
    Element Should Contain  css=div.form-content span.field_value.pre  81


TNR Filtre collectivités sur bordereau d'envoi de de courriers signature Maire

    [Documentation]  Contrôle que le bordereau d'envoi de courriers signature Maire affiche
    ...  seulement les dossiers de la collectivité de l'utilisateur en tant que mono, et
    ...  que le select de collectivité en tant qu'utilisateur multi fonctionne.

    Depuis la page d'accueil  instr  instr
    # Ajout de l'instruction Majoration de délai et des dates pour que le dossier
    # apparaisse dans notre bordereau
    Ajouter une instruction au DI et la finaliser  ${di}  Majoration délai SS en révision  ${date_jour}
    ${code_barres} =  Récupérer le code barre de l'instruction  Majoration délai SS en révision

    Depuis la page d'accueil  guichetsuivi  guichetsuivi
    Go To Submenu In Menu  suivi  suivi_mise_a_jour_des_dates
    Mettre à jour les dates de suivi  date d'envoi pour signature Mairie/Préfet  ${date_jour}  ${code_barres}

    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    # Ajout de l'instruction Majoration de délai et des dates pour que le dossier
    # apparaisse dans notre bordereau
    Ajouter une instruction au DI et la finaliser  ${di_allauch}  Majoration délai SS en révision  ${date_jour}
    ${code_barres_allauch} =  Récupérer le code barre de l'instruction  Majoration délai SS en révision

    Depuis la page d'accueil  guichetsuivi  guichetsuivi
    Go To Submenu In Menu  suivi  suivi_mise_a_jour_des_dates
    Mettre à jour les dates de suivi  date d'envoi pour signature Mairie/Préfet  ${date_jour}  ${code_barres_allauch}

    # Le bordereau d'envoi des avis du Maire au Préfet de Marseille doit afficher le
    # dossier "Martinez" de Marseille et pas "Sevier" d'ALLAUCH
    Depuis la page d'accueil  suivi  suivi
    Click Link  Bordereaux
    # On ne doit pas avoir le select de collectivité en temps que collectivité de niveau 1
    Page Should Not Contain  Collectivité
    Page Should Not Contain Errors
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Contain  Edition du${SPACE}${date_jour}
    Page Should Not Contain  Sevier
    Close PDF

    ${list_collectivites} =    Create List
    ...    Toutes
    ...    ALLAUCH
    ...    MARSEILLE

    Depuis la page d'accueil  admin  admin
    Go To Submenu In Menu  suivi  bordereau_envoi_maire
    Click Link  Bordereaux
    # Le select Collectivité doit être présent
    Page Should Contain  Collectivité
    Page Should Not Contain Errors
    # Le select doit contenir les 4 options
    Select List Should Contain List  om_collectivite  ${list_collectivites}
    # On affiche le bordereau de toutes les communes
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  om_collectivite  Toutes
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    # Le PDF doit contenir les dossiers des 2 communes mono et Toutes au lieu du nom de la
    # commune
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Contain  Toutes
    Page Should Contain  Sevier
    Close PDF

    # On affiche le bordereau des dossiers de Marseille
    Click Link  Bordereaux
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  om_collectivite  MARSEILLE
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Not Contain  Sevier
    # On doit avoir le code et nom de la commune
    Page Should Contain  013 055
    Page Should Contain  Marseille
    Close PDF


TNR Filtre collectivités sur bordereau d'envoi des décisions

    [Documentation]  Vérifie que le bordereau d'envoi des décisions affiche seulement les
    ...  dossiers de la collectivité de l'utilisateur en tant que mono, et que le select
    ...  de collectivité en tant qu'utilisateur multi fonctionne.

    Depuis la page d'accueil  instr  instr
    # Ajout de l'instruction accepter un dossier et des dates pour que le dossier
    # apparaisse dans notre bordereau
    Ajouter une instruction au DI et la finaliser  ${di}  accepter un dossier sans réserve  ${date_jour}
    ${code_barres} =  Récupérer le code barre de l'instruction  accepter un dossier sans réserve

    Depuis la page d'accueil  guichetsuivi  guichetsuivi
    Go To Submenu In Menu  suivi  suivi_mise_a_jour_des_dates
    Mettre à jour les dates de suivi  date d'envoi pour signature Mairie/Préfet  ${date_jour}  ${code_barres}

    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    # Ajout de l'instruction accepter un dossier et des dates pour que le dossier
    # apparaisse dans notre bordereau
    Ajouter une instruction au DI et la finaliser  ${di_allauch}  accepter un dossier sans réserve  ${date_jour}
    ${code_barres_allauch} =  Récupérer le code barre de l'instruction  accepter un dossier sans réserve
    #
    Depuis la page d'accueil  guichetsuivi  guichetsuivi
    Go To Submenu In Menu  suivi  suivi_mise_a_jour_des_dates
    Mettre à jour les dates de suivi  date d'envoi pour signature Mairie/Préfet  ${date_jour}  ${code_barres_allauch}

    # Le bordereau d'envoi des avis du Maire au Préfet de Marseille doit afficher le
    # dossier "Martinez" de Marseille et pas "Sevier" d'ALLAUCH
    Depuis la page d'accueil  suivi  suivi
    Click On Link  Bordereaux
    Page Title Should Be  Suivi > Suivi Des Pièces > Bordereaux
    Ouvrir le bordereau de suivi  Bordereau d'envoi des décisions
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Contain  Edition du${SPACE}${date_jour}
    Page Should Not Contain  Sevier
    Close PDF


    Depuis la page d'accueil  admin  admin
    Go To Submenu In Menu  suivi  bordereau_envoi_maire
    Click Link  Bordereaux

    # Le bordereau de toutes les communes doit contenir les 2 dossiers
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  om_collectivite  Toutes
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Contain  Sevier
    Close PDF

    Click Link  Bordereaux
    # L'option Allauch doit afficher seulement le dossier d'Allauch
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  om_collectivite  ALLAUCH
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Sevier
    Page Should Not Contain  Chesnay Roger
    Close PDF

    # Permet de réutiliser le code d'instruction dans les autres test cases
    Set Suite Variable  ${code_barres}
    Set Suite Variable  ${code_barres_allauch}


TNR Filtre collectivités sur bordereau d'envoi des contrôles de légalité

    [Documentation]  Vérifie que le bordereau d'envoi des contrôles de légalité affiche
    ...  les dossiers de la collectivité de l'utilisateur en tant que mono, et que le
    ...  select de collectivité en tant qu'utilisateur multi fonctionne.

    Depuis la page d'accueil  guichetsuivi  guichetsuivi
    Go To Submenu In Menu  suivi  suivi_mise_a_jour_des_dates
    Mettre à jour les dates de suivi  date d'envoi au contrôle de légalite  ${date_jour}  ${code_barres}
    Mettre à jour les dates de suivi  date d'envoi au contrôle de légalite  ${date_jour}  ${code_barres_allauch}

    # Le bordereau d'envoi des avis du Maire au Préfet de Marseille doit afficher le
    # dossier "Martinez" de Marseille et pas "Sevier" d'ALLAUCH
    Depuis la page d'accueil  suivi  suivi
    Click Link  Bordereaux
    Ouvrir le bordereau de suivi  Bordereau d'envoi des contrôles de légalité
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Contain  Edition du${SPACE}${date_jour}
    Page Should Not Contain  Sevier
    Close PDF


    Depuis la page d'accueil  admin  admin
    Go To Submenu In Menu  suivi  bordereau_envoi_maire
    Click Link  Bordereaux

    # L'option Toutes du select doit afficher les dossiers des 2 communes
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  om_collectivite  Toutes
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Contain  Sevier
    Close PDF

    Click Link  Bordereaux
    # L'option Allauch doit afficher seulement le dossier d'Allauch
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  om_collectivite  ALLAUCH
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Sevier
    Page Should Not Contain  Chesnay Roger
    Close PDF


TNR Filtre collectivités sur bordereau d'envoi des avis du Maire au Préfet

    [Documentation]  Vérifie que le bordereau d'envoi des avis du Maire au Préfet affiche
    ...  les dossiers de la collectivité de l'utilisateur en tant que mono, et que le
    ...  select de collectivité en tant qu'utilisateur multi fonctionne.

    Depuis la page d'accueil  suivi  suivi
    # Met à jour les dates d'envoi de lettre RAR
    Envoi lettre RAR pour l'instruction  ${date_jour}  ${code_barres}
    Envoi lettre RAR pour l'instruction  ${date_jour}  ${code_barres_allauch}

    Depuis la page d'accueil  instr  instr
    # Ajout de l'instruction Changer l'autorité compétente 'commune état' pour que le
    # dossier apparaisse dans notre bordereau
    Ajouter une instruction au DI  ${di}  Changer l'autorité compétente 'commune état'  ${date_jour}
    Element Should Contain  css=div.ui-state-valid  Vos modifications ont bien été enregistrées.
    Click On Back Button In Subform

    Depuis la page d'accueil  instrpolycomm3  instrpolycomm3
    # Ajout de l'instruction Changer l'autorité compétente 'commune état' pour que le
    # dossier apparaisse dans notre bordereau
    Ajouter une instruction au DI  ${di_allauch}  Changer l'autorité compétente 'commune état'  ${date_jour}
    Element Should Contain  css=div.ui-state-valid  Vos modifications ont bien été enregistrées.
    Click On Back Button In Subform

    # Le bordereau d'envoi des avis du Maire au Préfet de Marseille doit afficher le
    # dossier "Martinez" de Marseille et pas "Sevier" d'ALLAUCH
    Depuis la page d'accueil  suivi  suivi
    Click Link  Bordereaux
    Ouvrir le bordereau de suivi  Bordereau d'envoi des avis du Maire au Préfet
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Contain  Edition du${SPACE}${date_jour}
    Page Should Not Contain  Sevier
    Close PDF


    Depuis la page d'accueil  admin  admin
    Go To Submenu In Menu  suivi  bordereau_envoi_maire
    Click Link  Bordereaux

    # L'option Marseille doit afficher seulement le dossier de Marseille
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  om_collectivite  Toutes
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Contain  Sevier
    Close PDF

    Click Link  Bordereaux
    # L'option Marseille doit afficher seulement le dossier de Marseille
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Select From List By Label  om_collectivite  MARSEILLE
    Ouvrir le bordereau de suivi  Bordereau d'envoi de courriers signature Maire
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  Chesnay Roger
    Page Should Not Contain  Sevier
    Close PDF


Vérification du contenu de la lettre RAR

    [Documentation]  Vérifie plusieurs points sur l'affichage d'une planche RAR :
    ...  - le représentant d'une personne morale ;
    ...  - la division si la phase est paramétrée sur l'événement ;
    ...  - le code de la phase si la phase est paramétrée sur l'événement.

    #
    Depuis la page d'accueil  guichetsuivi  guichetsuivi
    #
    &{args_petitionnaire} =  Create Dictionary
    ...  qualite=personne morale
    ...  personne_morale_denomination=The Network Chef Inc.
    ...  personne_morale_raison_sociale=Société
    ...  personne_morale_civilite=Monsieur
    ...  personne_morale_nom=Barteaux
    ...  personne_morale_prenom=René
    #
    &{args_demande} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    #
    ${di_03} =  Ajouter la nouvelle demande depuis le tableau de bord  ${args_demande}  ${args_petitionnaire}

    #
    Depuis la page d'accueil  instr  instr
    #
    Depuis l'instruction du dossier d'instruction  ${di_03}  Notification du delai legal maison individuelle
    #
    ${instruction} =  Get Text  css=.form-content #instruction
    ${code_barres} =  STR_PAD_LEFT  ${instruction}  10  0
    ${code_barres} =  Catenate  11${code_barres}

    #
    Depuis la page d'accueil  suivi  suivi
    #
    Envoi lettre RAR pour l'instruction  ${date_jour}  ${code_barres}
    # On clic pour afficher la planche RAR
    Click Link  css=.pdf-16
    #
    Open PDF  form
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  PDF Pages Number Should Be  1
    # On vérifie que le réprésentant de la personne morale est affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  rep. par Barteaux René
    # On vérifie que la division ne soit pas affichée lorsque la phase n'est pas
    # paramétrée
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  subdivision H
    # On vérifie que le code de la phase ne soit pas affiché lorsque la phase
    # n'est pas paramétrée
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Not Contain  PINSTR
    #
    Close PDF

    #
    Depuis la page d'accueil  admin  admin
    #
    &{phase} =  Create Dictionary
    ...  code=INSTR
    Ajouter la phase  ${phase}
    # On lie la phase à l'événement "Notification du delai legal maison individuelle"
    &{args_evenement} =  Create Dictionary
    ...  libelle=Notification du delai legal maison individuelle
    ...  phase=INSTR
    #
    Modifier l'événement  ${args_evenement}

    #
    Depuis la page d'accueil  suivi  suivi
    #
    Envoi lettre RAR pour l'instruction  ${date_jour}  ${code_barres}
    # On clic pour afficher la planche RAR
    Click Link  css=.pdf-16
    #
    Open PDF  form
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  PDF Pages Number Should Be  1
    # On vérifie que le réprésentant de la personne morale est affiché
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  rep. par Barteaux René
    # On vérifie que la division est affichée lorsque la phase est paramétrée
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  subdivision H
    # On vérifie que le code de la phase est affiché lorsque la phase est
    # paramétrée
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain  INSTR
    #
    Close PDF
