trunk/tests/300_001_task.robot

*** Settings ***
Documentation  Test de task.

# On inclut les mots-clefs
Resource  resources/resources.robot
# On ouvre/ferme le navigateur au début/à la fin du Test Suite.
Suite Setup  For Suite Setup
Suite Teardown  For Suite Teardown


*** Variables ***
${alternate_filestorage}  filestorage_plop

*** Test Cases ***
Activation de l'option 'option_notification_piece_numerisee'
    [Documentation]  Il est nécessaire de faire cette manipulation pour éviter le
    ...  FAIL: Element with locator 'dossier_message_id' not found.

    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=true
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}

    Depuis la page d'accueil  admin  admin
    Rendre les types de dossier d'autorisation détaillés utilisés transmissible à Plat'AU  PCI
    Rendre les types de dossier d'autorisation détaillés utilisés transmissible à Plat'AU  DP


Verification calcul de l'instruction suivante lors de la récupération des id externes
    [Documentation]  Ce test vérifie que depuis lors de la récuperation des id externes le calcul
    ...  le calcul de numero de dossier se fait bien.
    Depuis la page d'accueil  admin  admin
    @{type_di} =  Create List  PCI - P - Initial
    @{etat_source} =  Create List  delai de notification envoye
    # Création des événements
    &{args_evenement_ACCORD2} =  Create Dictionary
    ...  libelle=ACCORD 2
    ...  retour=true
    ...  action=accepter un dossier
    ...  etat=dossier accepter
    Ajouter l'événement depuis le menu  ${args_evenement_ACCORD2}

    &{args_evenement_ACCORD1} =  Create Dictionary
    ...  libelle=ACCORD 1
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etat_source}
    ...  dossier_instruction_type=${type_di}
    ...  lettretype=arrete ARRETE
    ...  evenement_retour_ar=ACCORD 2
    ...  avis_decision=Favorable
    Ajouter l'événement depuis le menu  ${args_evenement_ACCORD1}

    &{args_demande_auto} =  Create Dictionary
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  om_collectivite=MARSEILLE
    &{args_petitionnaire_auto} =  Create Dictionary
    ...  particulier_nom=SEPTIM
    ...  particulier_prenom=MARTIN
    ...  om_collectivite=MARSEILLE
    ${di} =  Ajouter la demande par WS  ${args_demande_auto}  ${args_petitionnaire_auto}

    # Création du dossier
    Ajouter une instruction au DI et la finaliser  ${di}  ${args_evenement_ACCORD1.libelle}

    Click Element  css=#main
    ${numdossier} =  Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Get Text  css=#dossier_libelle
    ${numdossier_sans_espace} =  Sans espace  ${numdossier}
    Depuis l'onglet instruction du dossier d'instruction  ${di}
    &{args_instruction} =  Create Dictionary
    ...  date_retour_rar=${DATE_FORMAT_DD/MM/YYYY}
    Modifier le suivi des dates  ${di}  ACCORD 1  ${args_instruction}
    Depuis le contexte de la task via numero de dossier et son type sur le moniteur Plat'AU  ${numdossier_sans_espace}  Décision DI
    Open Fieldset  task  json_payload-calculee
    Element Should Contain  css=#json_payload  "path"


Vérification de l'ajout des tasks creation_DA, creation_DI, depot_DI et qualification_DI lors de l'ajout d'un dossier d'instruction.
    [Documentation]  Permet de vérifier le bon fonctionnement de la création des tâches lié à la création d'un dossier d'instruction
    ...  Vérifie aussi qu'il n'y a pas de création d'autre tâche non concerné
    Depuis la page d'accueil  admin  admin
    &{args_dossier} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  terrain_adresse_localite=TEST300AdresseLocalite
    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=particulier
    ...  particulier_nom=TEST300TASKNOM01
    ...  particulier_prenom=TEST300TASKPRENOM01
    ...  localite=TEST300Localite
    ...  om_collectivite=MARSEILLE
    ${di1} =  Ajouter la demande par WS  ${args_dossier}  ${args_petitionnaire1}

    &{donnees_techniques_values} =  Create Dictionary
    ...  enga_decla_lieu=TEST300engadelalieu
    ...  enga_decla_date=${date_ddmmyyyy}
    Saisir les données techniques du DI  ${di1}  ${donnees_techniques_values}

    Depuis le menu Moniteur Plat'AU

    ${di1_sans_espace} =  Sans espace  ${di1}
    ${di1_da} =  Replace String Using Regexp  ${di1_sans_espace}  [A-Z][0-9]+$  ${EMPTY}
    Set Suite Variable  ${di1}
    Set Suite Variable  ${di1_sans_espace}
    Set Suite Variable  ${di1_da}
    # On recherche l'enregistrement
    #
    Wait Until Element Is Visible  css=div#adv-search-adv-fields input#dossier
    Wait Until Element Is Visible  css=div#adv-search-adv-fields select#type
    # On remplit
    Input Text  css=div#adv-search-adv-fields input#dossier  ${di1_da}
    Select From List By Label  css=div#adv-search-adv-fields select#type  Création DA
    # On valide le formulaire de recherche
    Click On Search Button

    Element Should Contain  css=td.col-1 a.lienTable  Création DA
    Element Should Contain  css=td.col-4 a.lienTable  ${di1_da}

    # On remplit
    Input Text  css=div#adv-search-adv-fields input#dossier  ${di1_da}
    Select From List By Label  css=div#adv-search-adv-fields select#type  Création DI
    # On valide le formulaire de recherche
    Click On Search Button

    Element Should Contain  css=td.col-1 a.lienTable  Création DI
    Element Should Contain  css=td.col-4 a.lienTable  ${di1_da}

    # On remplit
    Input Text  css=div#adv-search-adv-fields input#dossier  ${di1_da}
    Select From List By Label  css=div#adv-search-adv-fields select#type  Dépôt DI
    # On valide le formulaire de recherche
    Click On Search Button

    Element Should Contain  css=td.col-1 a.lienTable  Dépôt DI
    Element Should Contain  css=td.col-4 a.lienTable  ${di1_da}

    # On remplit
    Input Text  css=div#adv-search-adv-fields input#dossier  ${di1_da}
    Select From List By Label  css=div#adv-search-adv-fields select#type  Qualification DI
    # On valide le formulaire de recherche
    Click On Search Button

    Element Should Contain  css=td.col-1 a.lienTable  Qualification DI
    Element Should Contain  css=td.col-4 a.lienTable  ${di1_da}

    Click On Link  ${di1_sans_espace}
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Page Should Contain Element  css=#task
    ${id_depot_DI} =  Get Text  css=#task
    ${id_next_task} =  Evaluate  ${id_depot_DI} + 1
    Vérifier qu'il n'y a pas de création d'autre tâche non concerné  ${id_next_task}  ${di1_da}


Vérification de la mise à jour de la task Création demande lors de l'ajout des données techniques
    [Documentation]  Permet de vérifier que la tâche Création demande est mise à jour sur son state est à "à traiter" lors de la modification du DI
    ...  et qu'il n'y a pas de création de tache Modification DI, vérifie aussi que lors que la tache Création demande n'est pas en state "à traiter"
    ...  il y a bien une création de la tâche Modification DI.
    ...  Vérifie également la création d'une tâche Modification DA lors de la modification des données techniques.
    Depuis la page d'accueil  admin  admin

    &{task_values} =  Create Dictionary
    ...  type=creation_DA
    ...  dossier=${di1_da}
    ...  state=new
    ...  object_id=${di1_da}
    ...  link_dossier=${di1_da}
    ...  stream=output
    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}
    ${id_creation_DA} =  Get Text  css=#task

    &{task_values} =  Create Dictionary
    ...  type=creation_DI
    ...  dossier=${di1_sans_espace}
    ...  state=new
    ...  object_id=${di1_sans_espace}
    ...  link_dossier=${di1_sans_espace}
    ...  stream=output
    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}
    ${id_creation_DI} =  Get Text  css=#task
    ${time_stamp_log} =  Get Text  css=#timestamp_log_jsontotab

    &{donnees_techniques_values} =  Create Dictionary
    ...  ope_proj_desc=Description test dossier parallele
    Saisir les données techniques du DI  ${di1}  ${donnees_techniques_values}
    Depuis le contexte d'une task à partir de la recherche avancée  ${task_values}
    ${timestamp_log_changed} =  Get Text  css=#timestamp_log_jsontotab

    Should Not Be Equal As Strings  ${time_stamp_log}  ${timestamp_log_changed}

    Click On Back Button

    # On vérifie qu'il n'y pas de task Modification DI
    ${passed} =  Run Keyword And Return Status  Element Should Not Contain  css=div#adv-search-adv-fields select#type  Modification DI
    Run Keyword If  ${passed}==False  Select From List By Label  css=select#type  Modification DI
    Run Keyword If  ${passed}==False  Click On Search Button
    Run Keyword If  ${passed}==False  Element Should Contain  css=#tab-task  Aucun enregistrement.

    &{task_values_modif} =  Create Dictionary
    ...  state=terminé
    Modifier la task  ${id_creation_DI}  ${task_values_modif}
    La page ne doit pas contenir d'erreur
    Modifier la task  ${id_creation_DA}  ${task_values_modif}
    La page ne doit pas contenir d'erreur

    &{donnees_techniques_values} =  Create Dictionary
    ...  ope_proj_desc=Description test dossier parallele BIS
    Saisir les données techniques du DI  ${di1}  ${donnees_techniques_values}
    La page ne doit pas contenir d'erreur

    &{task_values} =  Create Dictionary
    ...  type=modification_DI
    ...  dossier=${di1_sans_espace}
    Depuis le contexte d'une task à partir de la recherche avancée  ${task_values}

    # &{task_values} =  Create Dictionary
    # ...  type=Modification DA
    # ...  dossier=${di1_da}
    # Depuis le contexte d'une task à partir de la recherche avancée  ${task_values}


Vérification de l'ajout de la task qualification lors du changement de qualification d'un dossier d'instruction + modification manuelle d'une task
    [Documentation]  Permet de vérifier que la tâche Qualification DI est bien ajoutée lors du changement de l'autorité compétente.
    ...  Vérifie aussi qu'il n'y a pas de création d'autre tâche non concerné et que le object_id de la tâche pointe bien vers la
    ...  nouvelle instruction.
    ...  Dans un second temps, est vérifié la modification manuelle et son impact sur le timestamp_log.
    Depuis la page d'accueil  admin  admin
    ${instr_ac} =  Ajouter une instruction au DI  ${di1}  Changer l'autorité compétente 'commune état'
    &{task_values} =  Create Dictionary
    ...  type=qualification_DI
    ...  dossier=${di1_sans_espace}
    ...  state=new
    ...  object_id=${instr_ac}
    ...  link_dossier=${di1_sans_espace}
    ...  stream=output
    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}
    ${status} =  Run Keyword And Return Status  Click Element Until New Element  css=fieldset#fieldset-form-task-json_payload>legend  css=#json_payload
    Run Keyword If  '${status}' != 'True'  Click Element Until New Element  css=fieldset#fieldset-form-task-json_payload-calculee>legend  css=#json_payload
    Element Should Contain  css=#json_payload  "autorite_competente_code": "ETATMAIRE"

    Supprimer l'instruction  ${di1}  Changer l'autorité compétente 'commune état'
    ${instr_ac} =  Evaluate  ${instr_ac} - 1
    ${instr_ac} =  Convert to String  ${instr_ac}
    &{task_values} =  Create Dictionary
    ...  type=qualification_DI
    ...  dossier=${di1_sans_espace}
    ...  state=new
    ...  object_id=${instr_ac}
    ...  link_dossier=${di1_sans_espace}
    ...  stream=output
    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}
    ${id_task} =  Get Text  css=#task
    ${time_stamp_log} =  Get Value  css=#timestamp_log_hidden

    # Converti la payload JSON en dico python
    ${time_stamp_log_dic}=  Evaluate  ${time_stamp_log}
    # Récupérer le nombre d'entrée dans le timestamp_log
    ${nb_entree_timestamp_log} =  Get Length  ${time_stamp_log_dic}
    # Récupération du dernier index du timestamp_log
    ${last_index_timestamp_log} =  Evaluate  ${nb_entree_timestamp_log} - 1
    # On récupère la dernière entrée pour comparer les state
    ${before_last_state} =  Set Variable  ${time_stamp_log_dic[${last_index_timestamp_log}]["state"]}

    # Modification de la tâche en state = done
    Click On Form Portlet Action  task  modifier
    Wait Until Element Is Visible  css=#state
    Select From List By Label  css=div#form-container select#state  terminé
    Click On Submit Button
    ${time_stamp_log_bis} =  Get Value  css=#timestamp_log_hidden

    # Modifie le dossier 'a_qualifier' pour le passer en false et vérifier que l'info n'a pas été mise à jour dans la json payload, ce qui montre qu'on a bien figé la json payload
    Click On Link  ${di1_sans_espace}
    Element should Contain  css=#a_qualifier  Oui
    Click On Form Portlet Action  dossier_instruction  modifier
    Set Checkbox  a_qualifier  false
    Click On Submit Button
    Wait Until Keyword Succeeds  ${TIMEOUT}  ${RETRY_INTERVAL}  Valid Message Should Contain  Vos modifications ont bien été enregistrées.

    # On vérifie que la variable 'tax_surf_tot_cstr' des données techniques n'a pas été modifié, car la payload json doit être
    # figé pour les tâches de type 'output' et de statut 'done'
    Depuis le contexte de la task  ${id_task}
    ${status} =  Run Keyword And Return Status  Click Element Until New Element  css=fieldset#fieldset-form-task-json_payload>legend  css=#json_payload
    Run Keyword If  '${status}' != 'True'  Click Element Until New Element  css=fieldset#fieldset-form-task-json_payload-calculee>legend  css=#json_payload
    Element Should Contain  css=#json_payload  "a_qualifier": "t"

    # Converti la payload JSON en dico python
    ${time_stamp_log_dic} =  Evaluate  ${time_stamp_log_bis}
    # Récupérer le nombre d'entrée dans le timestamp_log
    ${nb_entree_timestamp_log_bis} =  Get Length  ${time_stamp_log_dic}
    # Récupération du dernier index du timestamp_log
    ${last_index_timestamp_log} =  Evaluate  ${nb_entree_timestamp_log_bis} - 1
    # On récupère la dernière entrée pour comparer les prev_state et state
    ${last_prev_state} =  Set Variable  ${time_stamp_log_dic[${last_index_timestamp_log}]["prev_state"]}
    ${last_state} =  Set Variable  ${time_stamp_log_dic[${last_index_timestamp_log}]["state"]}

    # On vérifie qu'une entrée supplémentaire à bien été prise en compte dans le timestamp_log
    Should Not Be Equal As Strings  ${nb_entree_timestamp_log}  ${nb_entree_timestamp_log_bis}
    # Comparaison entre le dernier prev_state avec l'avant dernier state
    Should Be Equal As Strings  ${last_prev_state}  ${before_last_state}
    # Vérification que le dernier state est bien à "done" suite à notre modification au-dessus
    Should Be Equal As Strings  ${last_state}  done

    # Modification de la tâche en state = done
    Click On Form Portlet Action  task  modifier
    Wait Until Element Is Visible  css=#comment
    Input Text  css=textarea#comment  CommentaireTest300
    Click On Submit Button

    Element Text Should Be  comment  CommentaireTest300
    ${time_stamp_log_comment} =  Get Value  css=#timestamp_log_hidden

    # Converti la payload JSON en dico python
    ${time_stamp_log_dic} =  Evaluate  ${time_stamp_log_comment}
    # Récupérer le nombre d'entrée dans le timestamp_log
    ${nb_entree_timestamp_log_comment} =  Get Length  ${time_stamp_log_dic}
    # Récupération du dernier index du timestamp_log
    ${last_index_timestamp_log} =  Evaluate  ${nb_entree_timestamp_log_comment} - 1
    # On récupère la dernière entrée pour vérifier la valeur du champs commentaire
    ${last_comment} =  Set Variable  ${time_stamp_log_dic[${last_index_timestamp_log}]["comment"]}

    # Vérification que le dernier commentaire est bien celui que l'on a ajouté lors de la dernière modification
    Should Be Equal As Strings  ${last_comment}  CommentaireTest300

    # Modification de la tâche en state = new
    Click On Form Portlet Action  task  modifier
    Wait Until Element Is Visible  css=#state
    Select From List By Label  css=div#form-container select#state  à traiter
    Click On Submit Button


Vérification de l'ajout de la task decision lors de l'ajout d'une décision dans le di
    [Documentation]  Permet de vérifier que la tâche Décision DI est bien ajoutée lors de l'ajout de la décision au dossier d'instruction
    ...  et que le contenu généré et téléchargé à partir de la tâche est identique.
    ...  Vérifie aussi qu'il n'y a pas de création d'autre tâche non concernée.
    ...  Vérifie également la gestion des mosidifcations d'une tâche en cours de traitement
    Depuis la page d'accueil  admin  admin
    ${instr_ad} =  Ajouter une instruction au DI et la finaliser  ${di1}  accepter un dossier sans réserve  true
    Click On SubForm Portlet Action  instruction  edition  new_window
    Open PDF  ${OM_PDF_TITLE}
    ${link_decision_portlet} =  Get Location
    Close PDF
    ${output_dir_decision_portlet}  ${output_name_decision_portlet}=  Télécharger un fichier  ${SESSION_COOKIE}  ${link_decision_portlet}  ${EXECDIR}${/}binary_files${/}

    &{task_values} =  Create Dictionary
    ...  type=decision_DI
    ...  dossier=${di1_sans_espace}
    ...  state=new
    ...  link_dossier=${di1_sans_espace}
    ...  stream=output
    ...  object_id=${instr_ad}
    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}
    ${id_decision_DI} =  Get Text  css=#task

    ${status} =  Run Keyword And Return Status  Click Element Until New Element  css=fieldset#fieldset-form-task-json_payload>legend  css=#json_payload
    Run Keyword If  '${status}' != 'True'  Click Element Until New Element  css=fieldset#fieldset-form-task-json_payload-calculee>legend  css=#json_payload
    Element Should Contain  css=#json_payload  "avis_decision": "7",

    ${json_payload_loaded} =  Récupérer le contenu du champ json_payload  ${task_values}
    ${link_decision} =  Set Variable  ${json_payload_loaded['instruction']['path']}
    ${output_dir_json_payload}  ${output_name_json_payload}=  Télécharger un fichier  ${SESSION_COOKIE}  ${PROJECT_URL}${link_decision}  ${EXECDIR}${/}binary_files${/}

    ${base64_file_portlet} =  Run  base64 ${output_dir_decision_portlet}${output_name_decision_portlet}
    ${base64_json_payload} =  Run  base64 ${output_dir_json_payload}${output_name_json_payload}
    Should Be Equal As Strings  ${base64_file_portlet}  ${base64_json_payload}

    ${id_decision_DI} =  Get Text  css=#task
    ${id_next_task} =  Evaluate  ${id_decision_DI} + 1
    Vérifier qu'il n'y a pas de création d'autre tâche non concerné  ${id_next_task}  ${di1_da}

    # Task considéré en cours de traitement pour vérifier que l'ajout d'une nouvelle décision,
    # ajoute une nouvelle tâche et ne modifie pas l'existante

    # Tâche considérée en cours de traitement
    &{task_values_modif} =  Create Dictionary
    ...  state=en cours
    Modifier la task  ${id_decision_DI}  ${task_values_modif}
    &{task_values} =  Create Dictionary
    ...  type=decision_DI
    ...  dossier=${di1_sans_espace}
    ...  state=pending
    ...  link_dossier=${di1_sans_espace}
    ...  stream=output
    ...  object_id=${instr_ad}
    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}

    # Ajout d'un événement de reprise pour ajouter à nouveau un événement de décision
    @{type_di} =  Create List
    ...  PCI - P - Initial
    &{args_action} =  Create Dictionary
    ...  action=reprise_instruction_300
    ...  libelle=reprise de l'instruction - 300
    ...  regle_etat=etat
    ...  regle_accord_tacite=accord_tacite
    ...  regle_avis=null
    ...  regle_date_validite=null
    ...  regle_date_decision=null
    Ajouter Action  ${args_action}
    @{etats_autorises} =  Create List  dossier accepter
    &{args_evenement_para} =  Create Dictionary
    ...  libelle=Reprise de l'instruction - 300_task
    ...  dossier_instruction_type=${type_di}
    ...  action=${args_action.libelle}
    ...  etats_autorises=${etats_autorises}
    ...  etats_depuis_lequel_l_evenement_est_disponible=${etats_autorises}
    ...  etat=delai de notification envoye
    ...  accord_tacite=Non
    Ajouter l'événement depuis le menu  ${args_evenement_para}
    ${instr_reprise} =  Ajouter une instruction au DI  ${di1}  ${args_evenement_para.libelle}
    # Vérifie que la reprise de l'instruction n'est pas altérée la tâche de décision
    # (un bug faisait que l'object_id était modifié par l'id de l'instruction de reprise)
    &{task_values} =  Create Dictionary
    ...  task=${id_decision_DI}
    Depuis le contexte d'une task à partir de la recherche avancée  ${task_values}
    Element Should Not Contain  css=#object_id  ${instr_reprise}
    Element Should Contain  css=#object_id  ${instr_ad}

    # Ajoute à nouveau une instruction de décision et vérifie que la task en cours de traitement
    # n'est pas altérée et qu'une nouvelle task a été ajoutée
    ${instr_ad_2} =  Ajouter une instruction au DI  ${di1}  accepter un dossier sans réserve
    &{task_values} =  Create Dictionary
    ...  type=decision_DI
    ...  dossier=${di1_sans_espace}
    ...  state=pending
    ...  link_dossier=${di1_sans_espace}
    ...  stream=output
    ...  object_id=${instr_ad}
    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}
    &{task_values} =  Create Dictionary
    ...  type=decision_DI
    ...  dossier=${di1_sans_espace}
    ...  state=new
    ...  link_dossier=${di1_sans_espace}
    ...  stream=output
    ...  object_id=${instr_ad_2}
    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}


Vérification de l'ajout de la task decision lors de l'ajout d'une décision tacite dans le di
    [Documentation]  Permet de vérifier que la tâche Décision DI est bien ajoutée lors de l'ajout de la décision tacite au dossier d'instruction
    ...  et que la tâche ne contient pas de fichier à télécharger.
    ...  Vérifie aussi qu'il n'y a pas de création d'autre tâche non concerné
    Depuis la page d'accueil  admin  admin
    &{args_dossier} =  Create Dictionary
    ...  om_collectivite=MARSEILLE
    ...  dossier_autorisation_type_detaille=Permis de construire pour une maison individuelle et / ou ses annexes
    ...  demande_type=Dépôt Initial
    ...  terrain_adresse_localite=TEST300AdresseLocalite
    ...  depot_electronique=true
    ...  source_depot=platau
    &{args_petitionnaire1} =  Create Dictionary
    ...  qualite=particulier
    ...  particulier_nom=TEST300TASKNOM02
    ...  particulier_prenom=TEST300TASKPRENOM02
    ...  localite=TEST300Localite
    ...  om_collectivite=MARSEILLE
    ${di2} =  Ajouter la demande par WS  ${args_dossier}  ${args_petitionnaire1}

    &{donnees_techniques_values} =  Create Dictionary
    ...  enga_decla_lieu=TEST300engadelalieu
    ...  enga_decla_date=${date_ddmmyyyy}
    Saisir les données techniques du DI  ${di2}  ${donnees_techniques_values}

    ${di2_sans_espace} =  Sans espace  ${di2}
    ${di2_da} =  Replace String Using Regexp  ${di2_sans_espace}  [A-Z][0-9]+$  ${EMPTY}

    Ajouter une instruction au DI  ${di2}  accord tacite (sans arrete)

    &{task_values} =  Create Dictionary
    ...  type=decision_DI
    ...  dossier=${di2_sans_espace}
    Depuis le contexte d'une task à partir de la recherche avancée  ${task_values}
    ${json_payload_loaded} =  Récupérer le contenu du champ json_payload  ${task_values}

    Dictionary Should Not Contain Key  ${json_payload_loaded['instruction']}  path

    ${id_decision_DI} =  Get Text  css=#task
    ${id_next_task} =  Evaluate  ${id_decision_DI} + 1
    Vérifier qu'il n'y a pas de création d'autre tâche non concerné  ${id_next_task}  ${di1_da}


Vérification de l'ajout et de la consultation d'une tâche de type stream input
    [Documentation]  Permet de vérifier que l'ajout de la tâche à partir du WS de test
    ...  fonctionne correctement

    # Récupère le template de payload JSON et le transforme en dictionnaire
    ${json_payload} =  Get File  ${EXECDIR}${/}binary_files${/}json_payload_ref.txt
    ${json_payload} =  Replace String  ${json_payload}  7XY-DK8-5X  000-AAA-00
    ${json_payload} =  Replace String  ${json_payload}  3XY-DK4-7X  AAA-000-00
    ${json_payload} =  Replace String  ${json_payload}  013055 20  013055 19
    ${json_payload} =  Replace String  ${json_payload}  01305520  01305519
    ${json_payload} =  Replace String  ${json_payload}  2020  2019
    ${json_payload} =  Replace String  ${json_payload}  07777P0  01111P0
    ${json_payload} =  Replace String  ${json_payload}  "acteur": "EF-DSQ-4512",  ${EMPTY}
    ${payload_dict} =  To Json  ${json_payload}

    # Les attributs state et stream ne sont pas nécessaires lors de l'ajout de la tache
    # Ici ces attributs sont utilisés lors de la vérification des données de la tâches en consultation
    ${task_values} =  Create Dictionary
    ...  type=create_DI_for_consultation
    ...  json_payload=${json_payload}
    Ajouter la tâche par WS  ${task_values}

    # ajout manuellement les éléments qui ont du être défini par défaut
    Set To Dictionary  ${task_values}  dossier=${payload_dict["dossier"]["dossier"]}
    Set To Dictionary  ${task_values}  state=new
    Set To Dictionary  ${task_values}  stream=input

    Depuis la page d'accueil  admin  admin
    Depuis le contexte d'une task à partir de la recherche avancée  ${task_values}

    Vérifier que la tâche a bien été ajoutée ou modifiée  ${task_values}
    ${status} =  Run Keyword And Return Status  Click Element Until New Element  css=fieldset#fieldset-form-task-json_payload>legend  css=#json_payload
    Run Keyword If  '${status}' != 'True'  Click Element Until New Element  css=fieldset#fieldset-form-task-json_payload-calculee>legend  css=#json_payload
    ${json_payload_to_compare} =  Get Text  css=#json_payload
    ${json_payload_to_compare} =  Evaluate  json.loads('''${json_payload_to_compare}''')  json
    ${json_payload_to_compare} =  Set Variable  ${json_payload_to_compare["external_uids"]}

    ${json_payload_loaded} =  Evaluate  json.loads('''${json_payload}''')  json
    ${json_payload_loaded} =  Set Variable  ${json_payload_loaded["external_uids"]}

    Should Be Equal As Strings  ${json_payload_loaded}  ${json_payload_to_compare}

    Element Should Contain  css=#json_payload  "tax_statut_info": "Déclaré"


Rendre les types de dossier d'autorisation détaillés utilisés non transmissible à Plat'AU
    [Documentation]  Il est nécessaire de faire cette manipulation pour revenir à un état normal
    Depuis la page d'accueil  admin  admin
    &{args_type_DA_detaille_modification} =  Create Dictionary
    ...  dossier_platau=false
    Modifier type de dossier d'autorisation détaillé  PCI  ${args_type_DA_detaille_modification}
    Modifier type de dossier d'autorisation détaillé  DP  ${args_type_DA_detaille_modification}


Désactivation de l'option 'option_notification_piece_numerisee'
    [Documentation]  Il est nécessaire de faire cette manipulation pour éviter le
    ...  FAIL: Element with locator 'dossier_message_id' not found.

    &{om_param} =  Create Dictionary
    ...  libelle=option_notification_piece_numerisee
    ...  valeur=false
    ...  om_collectivite=agglo
    Gerer le paramètre par WS  ${om_param}
